1 Chap 10. Counting Like a Computer

#목적 : 정수를 스크린에 출력하기 위해 문자열로 바꾼다
#
#입력: 최대 숫자까지 저장할 수 있는 충분히 큰 버퍼
#        변환할 정수
#
#출력: 십진수 문자열이 저장된 버퍼
#
#변수:
#
# %ecx 현재 처리되고 있는 문자열의 카운터
# %eax 현재 값
# %edi 진수 값 10
#
.equ ST_VALUE, 8
.equ ST_BUFFER, 12

.globl integer2string
.type integer2string, @function
integer2string:
#함수 시작을 위한 스택 보존
pushl %ebp
movl %esp, %ebp

#현재 문자열의 크기
movl $0, %ecx

#파라미터로 전달된 값을 읽어온다
movl ST_VALUE(%ebp), %eax

#10으로 나누기 위해서는 10을 레지스터에 저장해놔야 한다
movl $10, %edi

conversion_loop:
#나눗셈은 %edx:%eax 레지스터 쌍에서 이루어진다
#따라서 %edx에는 0을 넣어논다
movl $0, %edx

#10으로 나눈다.
#몫은 %eax에 저장되고 나머지는 %edx에 저장된다
divl %edi


#%edx에 저장된 나머지를 문자로 변환해야 한다.
#10으로 나눈 나머지 값은 0에서 9사이의 값이 된다.
#따라서 이 수를 가지고 아스키 테이블의 '0'의 값을 기준으로 변환하면 된다.
#'0'에 0을 더하면 아스키 코드로 '0'이 되고 1을 더하면 '1'이 된다.
#따라서 다음과 같이 '0'에 나머지 값을 더하면 아스키 코드가 된다.
addl $’0’, %edx


#이제 변환된 값을 스택에 저장한다.
#이렇게 스택에 값을 저장한 다음에 한글자씩 꺼내서 버퍼에 저장하면
#글자 순서가 바로 잡히게 된다.
#레지스터 전체 값을 저장하지만 %dl 에 저장된 한 바이트가
#문자를 저장하고 있다는 것을 주의하자
pushl %edx

#자리수 카운터를 증가시킨다
incl %ecx

#%eax가 0인지 확인해서
#0이면 루프를 벗어난다
cmpl $0, %eax
je end_conversion_loop

#%eax 에는 새로 나누어야 할 값이 저장되어 있다

jmp conversion_loop

end_conversion_loop:
#문자열은 스택에 저장되어 있다. 
#한글자씩 써내서 버퍼에 저장해야 한다.

#%edx에 버퍼의 포인터를 저장한다
movl ST_BUFFER(%ebp), %edx

copy_reversing_loop:
#레지스터 전체를 스택에 저장했기 때문에
#마지막 한 바이트만 필요하게 된다.
#따라서 %eax에 스택의 값을 저장한 다음
#%al만 문자열에 저장한다.
popl %eax
movb %al, (%edx)

#%ecx에 저장된 자리수 카운터를 감소시켜서 언제 끝내야 할지 계산한다
decl %ecx
#%edx를 증가시켜서 다음에 문자를 저장할 포인터를 계산한다
incl %edx

#%ecx가 0이면 끝낸다.
cmpl $0, %ecx
#함수의 끝으로 점프한다
je end_copy_reversing_loop
#아니면 반복한다
jmp copy_reversing_loop

end_copy_reversing_loop:
#문자열 끝에 널을 저장하고 함수를 끝낸다.
movb $0, (%edx)

movl %ebp, %esp
popl %ebp
ret

.include "linux.s"

.section .data

tmp_buffer:
.ascii "\0\0\0\0\0\0\0\0\0\0\0"

.section .text

.globl _start
_start:
movl %esp, %ebp

#결과 값이 저장될 버퍼
pushl $tmp_buffer
#변환된 숫자
pushl $824
call integer2string
addl $8, %esp

#우리가 만든 함수로 몇 글자인지 확인한다
pushl $tmp_buffer
call count_chars
addl $4, %esp

#SYS_WRITE를 위해서 결과 값을 %edx에 저장한다.
movl %eax, %edx

#시스템 콜을 실행하기 위해 준비
movl $SYS_WRITE, %eax
movl $STDOUT, %ebx
movl $tmp_buffer, %ecx

int $LINUX_SYSCALL

#개행 문자를 쓴다
pushl $STDOUT
call write_newline

#프로그램 종료
movl $SYS_EXIT, %eax
movl $0, %ebx
int $LINUX_SYSCALL

as integer-to-string.s -o integer-to-number.o
as count-chars.s -o count-chars.o
as write-newline.s -o write-newline.o
as conversion-program.s -o conversion-program.o
ld integer-to-number.o count-chars.o write-newline.o conversion-program.o -o conversion-program